!! Manage air relative humidity with arbitrary time cumulation
!|author:  <a href="mailto:giovanni.ravazzani@polimi.it">Giovanni Ravazzani</a>
! license: <a href="http://www.gnu.org/licenses/">GPL</a>
!    
!### History
!
! current version 1.0 - 3rd June 2021 
!
! | version  |  date       |  comment |
! |----------|-------------|----------|
! | 1.0      | 3/June/2021 | Original code |
!
!### License  
! license: GNU GPL <http://www.gnu.org/licenses/>
!
!### Module Description 
!   Module to manage air relative humidity with arbitrary time cumulation
MODULE AirRelativeHumidity

! Modules used: 

USE DataTypeSizes, ONLY : &  
  ! Imported Parameters:
  float, short


USE Loglib, ONLY : &
  !Imported routines:
  Catch

USE ObservationalNetworks, ONLY : &
  !Imported types:
  ObservationalNetwork, &
  !Imported routines:
  ReadMetadata, ReadData, &
  CopyNetwork, &
  !Imported operators:
  ASSIGNMENT (=)

USE Chronos, ONLY : &
  !Imported types:
  DateTime, &
  !Imported variables:
  timeString, &
  !Imported operations:
  OPERATOR (<), &
  OPERATOR (>), &
  OPERATOR (>=), &
  OPERATOR (<=), &
  OPERATOR (+), &
  OPERATOR (==), &
  ASSIGNMENT (=)

USE GridLib, ONLY : &
  !Imported types:
  grid_real, grid_integer, &
  !Imported routines:
  NewGrid, GetDtGrid, &
  GridDestroy, ExportGrid, &
  SetLongName, SetStandardName, &
  SetUnits, SetCurrentTime, &
  !Imported parameters:
  NET_CDF, ESRI_ASCII, &
  ESRI_BINARY
  

USE GridOperations, ONLY : &
  !Imported routines:
  GridByIni, GridResample, &
  CRSisEqual, GridConvert, &
  !Imported operations:
  ASSIGNMENT (=)

USE IniLib, ONLY : &
  !Imported types:
  IniList, &
  !Imported routines:
  IniReadInt, IniReadReal, &
  KeyIsPresent, IniReadString, &
  SubSectionIsPresent

USE Utilities, ONLY: &
  !Imported routines:
  GetUnit

USE MeteoUtilities, ONLY: &
  !Imported routines:
  ReadField,  Interpolate, &
  Offset, Scale

USE FileSys, ONLY: &
  !Imported routines:
  DirExists, FileExists, &
  FileDelete, CurrentDir, &
  GetOS, DirNew, &
  !Imported parameters:
  WIN32

USE GeoLib, ONLY: &
  !Imported variables:
  point1, point2, &
  !Imported routines:
  DecodeEPSG, Convert, &
  !Imported types:
  CRS, &
  !Imported operations:
  OPERATOR (==)

USE StringManipulation, ONLY: &
   !Imported routines:
   ReplaceChar, ToString
    
IMPLICIT NONE 

! Global (i.e. public) Declarations: 

INTEGER (KIND = short)     :: dtRelHumidity  = 0 !!cumulation deltat 
TYPE(ObservationalNetwork) :: hygrometers !! sensor stations network
TYPE(grid_real)            :: relHumidityAir    !![% 0-100]


!Private declarations
TYPE(DateTime), PRIVATE         :: timeNew !!time when new  data must be read
INTEGER (KIND = short), PRIVATE :: fileunit !! unit of file containing  data
INTEGER (KIND = short), PRIVATE :: interpolationMethod  !!method to spatial interpolate site data
INTEGER (KIND = short), PRIVATE :: interpolationMethod_assignment  !!method to assign spatial interpolation !
                                                                   !!1 = one method for the entire domain, 2 = a map with interpolation method codes
TYPE (grid_integer),    PRIVATE :: interpolationMethod_map
INTEGER (KIND = short), PRIVATE :: interpolationMethod_vector (3) !!defines active interpolation methods 
TYPE (grid_real),       PRIVATE :: interpolatedMap (3)  !!1 = map for thiessen, 2 = map for idw, 3 = map for kriging
REAL (KIND = float),    PRIVATE :: cellsizeInterpolation !!spatial resolution of interpolated grid
INTEGER (KIND = short), PRIVATE :: neighbors  !!number of closest data to use for interpolation
TYPE(grid_real),        PRIVATE :: grid_devst !!standard deviation of kriging interpolation
CHARACTER (LEN = 300),  PRIVATE :: fileGrid !!file containing grids
INTEGER (KIND = short), PRIVATE :: dtGrid !!dt of imported  field
INTEGER (KIND = short), PRIVATE :: i, j  !!loop index
REAL (KIND = float), PARAMETER, PRIVATE :: refElevation = 1000. !!reference elevation for applying lapse rate
REAL (KIND = float), PRIVATE, PARAMETER :: MISSING_DEF_REAL = -9999.9
REAL (KIND = float), PRIVATE  :: scale_factor  !!scale factor to apply to final map
REAL (KIND = float), PRIVATE  :: offset_value !!offset to apply to final map
REAL (KIND = float), PRIVATE  :: valid_prcn !!when data from several time steps are read, 
                                      !!this is the minimum percentage (0-1) of valid 
                                       !!data that must be prresent to consider 
                                      !!valid the aggregated value.

!used by inverse distance weighting interpolation
REAL (KIND = float), PRIVATE :: idw_power !! power to be used with IDW

!used by kriging
INTEGER (KIND = short), PRIVATE :: krige_var !! when set to 1 a grid of kriging variance is generated and exported if export option is active, default to 0
INTEGER (KIND = short), PRIVATE :: krige_anisotropy !! considers anisotropy, default = 0 excludes anisotropy
INTEGER (KIND = short), PRIVATE :: krige_varmodel !! 1 = spherical, 2 = exponential, 3 = gaussian, 0 = automatic fitting. default to 2
INTEGER (KIND = short), PRIVATE :: krige_lags !! number of lags for semivariogram. if undefined or set to 0 default to 15
REAL (KIND = float)   , PRIVATE :: krige_maxlag !! maximum distance to be considered for semivariogram assessment. If undefined or set to 0, it is computed automatically

INTEGER (KIND = short), PRIVATE :: export !!activates grid exporting
CHARACTER (LEN = 1000), PRIVATE :: export_path  !!folder where to put exported grids
CHARACTER (LEN = 1000), PRIVATE :: export_file  !!name of  exported  grid
CHARACTER (LEN = 1000), PRIVATE :: export_file_var  !!name of  exported  variance grid
TYPE (DateTime), PRIVATE :: export_start   !! time and date to start exporting
TYPE (DateTime), PRIVATE :: export_stop !! time and date to stop exporting
INTEGER (KIND = short), PRIVATE ::  export_dt !! time between two exportations
TYPE (DateTime), PRIVATE :: timeNewExport !! time when new exporting must occur
INTEGER (KIND = short), PRIVATE :: export_format !! 1 = esri_ascii, 2 = esri_binary, 3 = netcdf 
INTEGER (KIND = short), PRIVATE :: export_epsg !! coordinate reference system of exported grid 
TYPE (grid_real), PRIVATE :: exportedGrid, exportedGridVar
TYPE (CRS), PRIVATE :: exportGridMapping
LOGICAL, PRIVATE   :: needConversion



!Public routines
PUBLIC :: AirRelativeHumidityInit
PUBLIC :: AirRelativeHumidityRead


!Local routines
PRIVATE :: SetSpecificProperties


!=======
CONTAINS
!=======
! Define procedures contained in this module.

!==============================================================================
!| Description:
!   Initialize air relative humidity
SUBROUTINE AirRelativeHumidityInit &
!
( ini, mask, dtMeteo, tstart )

IMPLICIT NONE

TYPE (IniList), INTENT(IN) :: ini
TYPE (grid_integer), INTENT(IN) :: mask  !!defines interpolation extent
INTEGER (KIND = short), INTENT(IN) :: dtMeteo !! deltat of meteo data reading
TYPE (DateTime),     INTENT(IN) :: tstart !!initial time


!local declarations
CHARACTER (LEN = 1000) :: filename
TYPE (grid_real) :: meteoTemp


!-------------------------end of declarations----------------------------------
!set initial time
  timeNew = tstart  

  !initialize grid
  CALL NewGrid (relHumidityAir, mask, 0.)
  CALL NewGrid (grid_devst, mask, 0.)
  
  !set deltat
  dtRelHumidity = IniReadInt ('dt', ini, section = 'relative-humidity')

  !check dt is multiple of dtMeteo
  IF (.NOT.(MOD(dtRelHumidity,dtMeteo) == 0)) THEN
           CALL Catch ('error', 'AirRelativeHumidity',   &
		                 'dt is not multiple of dtMeteo')
  END IF
  
  !set valid threshold
  IF (KeyIsPresent ('valid-threshold', ini, &
                         section = 'relative-humidity') ) THEN
      valid_prcn = IniReadReal ('valid-threshold', ini, &
                                        section = 'relative-humidity')
  ELSE ! set to default = 1.0 
      CALL Catch ('info', 'AirRelativeHumidity',   &
		                 'valid-threshold not defined, set to 1')
      valid_prcn = 1.
  END IF

  !set cell-size
  cellsizeInterpolation = mask % cellsize
  
  !interpolation-assignment method
  IF (KeyIsPresent('interpolation-assignment', ini, &
                     section = 'relative-humidity') ) THEN
      interpolationMethod_assignment = IniReadInt ('interpolation-assignment', ini, &
                                    section = 'relative-humidity')
  ELSE
    CALL Catch ('error', 'AirRelativeHumidity',   &
                'interpolation-assignment missing in meteo configuration file')
  END IF   

  !set interpolation method
  IF (interpolationMethod_assignment == 1) THEN

      interpolationMethod = IniReadInt ('interpolation', ini, &
                                    section = 'relative-humidity')
      
	    CALL SetSpecificProperties (interpolationMethod, ini, mask)
  
  ELSE !read map
      interpolationMethod = -1
      CALL GridByIni (ini, interpolationMethod_map, 'relative-humidity', &
                     'interpolation')
      !scan for interpolation methods included
      interpolationMethod_vector = 0
      DO i = 1, interpolationMethod_map % idim
        DO j = 1, interpolationMethod_map % jdim
            IF (interpolationMethod_map % mat(i,j) /= &
                interpolationMethod_map % nodata) THEN
                interpolationMethod_vector &
                   (interpolationMethod_map % mat (i,j)) = &
                    interpolationMethod_map % mat (i,j)
            END IF
        END DO
      END DO

      DO i = 1, 3
         CALL SetSpecificProperties (interpolationMethod_vector (i), ini, mask)
      END DO

  END IF

  !scale factor and offset
	IF (KeyIsPresent('offset', ini, section = 'relative-humidity')) THEN	
	   offset_value = IniReadReal ('offset', ini, section = 'relative-humidity')
	ELSE
	    offset_value = MISSING_DEF_REAL
	END IF
	
	IF (KeyIsPresent('scale-factor', ini, section = 'relative-humidity')) THEN	
	   scale_factor = IniReadReal ('scale-factor', ini, section = 'relative-humidity')
	ELSE
	    scale_factor = MISSING_DEF_REAL
	END IF			

   !set power_idw
   IF (KeyIsPresent('idw-power', ini, section = 'relative-humidity')) THEN	
	   idw_power = IniReadReal ('idw-power', ini, section = 'relative-humidity')
   ELSE !set default value
	    idw_power = 2.
   END IF	
 
	!file
    filename = IniReadString ('file', ini, section = 'relative-humidity')
    IF (interpolationMethod_assignment == 1 .AND. &
        interpolationMethod == 0) THEN !data are stored in net-cdf file
       !store net-cdf filename
       fileGrid = filename
       IF ( KeyIsPresent ('variable', ini, section = 'relative-humidity') ) THEN
          relHumidityAir % var_name = IniReadString ('variable', &
                                             ini, section = 'relative-humidity')
            !read grid and store as temporary file
             CALL NewGrid (layer = meteoTemp, fileName = TRIM(fileGrid), &
                         fileFormat = NET_CDF, &
                         variable = TRIM(relHumidityAir % var_name) )
       ELSE IF  (KeyIsPresent ('standard_name', ini, &
                              section = 'relative-humidity') ) THEN
          relHumidityAir % standard_name = IniReadString ('standard_name', &
                                              ini, section = 'relative-humidity')
       ELSE
          CALL Catch ('error', 'AirRelativeHumidity',   &
		       'standard_name or variable missing in section temeprature' )
       END IF      

       !set cellsize to zero. Optimal cellsize is automatically computed
       cellsizeInterpolation = 0.
            
    ELSE !open file containing local measurements
       fileunit = GetUnit ()
	     OPEN(fileunit,file = filename(1:LEN_TRIM(filename)),status='old')
    END IF
    

  !grid exporting settings
  IF (KeyIsPresent ('export', ini, section = 'relative-humidity')  )  THEN
     export = IniReadInt ('export', ini, section = 'relative-humidity')
  ELSE
     export = 0
  END IF 

  IF (export == 1) THEN
     
     !set export path name
     IF (KeyIsPresent ('export-path', ini, section = 'relative-humidity')  )  THEN
         export_path = IniReadString ('export-path', ini, section = 'relative-humidity')
         !check if path ends with / or \
         IF (  export_path (LEN_TRIM (export_path):LEN_TRIM (export_path)) /= '\' .AND. &
               export_path (LEN_TRIM (export_path):LEN_TRIM (export_path)) /= '/' ) THEN
             export_path (LEN_TRIM (export_path)+1:LEN_TRIM (export_path)+1) = '\'
         END IF
       
         IF (INDEX (export_path,'.') == 1) THEN !detected relative path, remove '.'
            export_path = export_path (2:LEN_TRIM(export_path))
            !build absolute path
            export_path = TRIM(CurrentDir() ) // TRIM(export_path)
         END IF

         !check OS convention
        IF (GetOS () == WIN32) THEN
          export_path = ReplaceChar (export_path,'/','\')
        ELSE
          export_path = ReplaceChar (export_path,'\','/')
        END IF
  
         
         !check folder exists
         IF ( .NOT. DirExists (TRIM (export_path) ) ) THEN
             CALL Catch ('info', 'AirRelativeHumidity',   &
                  'creating directory:  ', argument = TRIM(export_path))
             CALL DirNew (export_path)
         END IF
     ELSE
         CALL Catch ('error', 'AirRelativeHumidity',   &
                  'missing export-path')
     END IF 
     
     !starting time
     IF (KeyIsPresent ('export-start', ini, section = 'relative-humidity')  )  THEN
         timeString = IniReadString ('export-start', ini, 'relative-humidity')
         export_start = timeString
     ELSE
         CALL Catch ('error', 'AirRelativeHumidity',   &
                  'missing export-start')
     END IF 
     
     !initialize timeNewExport
     timeNewExport = export_start
     
     !ending time
     IF (KeyIsPresent ('export-stop', ini, section = 'relative-humidity')  )  THEN
         timeString = IniReadString ('export-stop', ini, 'relative-humidity')
         export_stop = timeString
     ELSE
         CALL Catch ('error', 'AirRelativeHumidity',   &
                  'missing export-start')
     END IF 
     
     !export dt
     IF (KeyIsPresent ('export-dt', ini, section = 'relative-humidity')  )  THEN
         export_dt = IniReadInt ('export-dt', ini, section = 'relative-humidity')
     ELSE
         CALL Catch ('error', 'AirRelativeHumidity',   &
                  'missing export-dt')
     END IF 

     !coordinate reference system
     IF (KeyIsPresent ('export-epsg', ini, section = 'relative-humidity')  )  THEN
         export_epsg = IniReadInt ('export-epsg', ini, section = 'relative-humidity')
         
         exportGridMapping = DecodeEPSG (export_epsg)
         IF (exportGridMapping == relHumidityAir % grid_mapping) THEN
            needConversion = .FALSE.
            !initialize grid for exporting with CRS as meteo variable
            CALL NewGrid (exportedGrid, relHumidityAir)
            CALL NewGrid (exportedGridVar, relHumidityAir)
         ELSE
            needConversion = .TRUE.
            !initialize grid for converting with required CRS
            exportedGrid % grid_mapping = DecodeEPSG (export_epsg)
            exportedGridVar % grid_mapping = DecodeEPSG (export_epsg)
         END IF
     ELSE
         CALL Catch ('info', 'AirRelativeHumidity',   &
                  'export-epsg not defined, use default')
         needConversion = .FALSE.
         !initialize grid for exporting with CRS 
         CALL NewGrid (exportedGrid, relHumidityAir)
         CALL NewGrid (exportedGridVar, relHumidityAir)
     END IF 

     !export file format 
     IF (KeyIsPresent ('export-format', ini, section = 'relative-humidity')  )  THEN
         export_format = IniReadInt ('export-format', ini, section = 'relative-humidity')
     ELSE
         CALL Catch ('error', 'AirRelativeHumidity',   &
                  'missing export-format')
     END IF 

     IF (export_format == 3) THEN
       !grid map  
       CALL SetLongName ( 'relative_humidity', exportedGrid)
       CALL SetStandardName ( 'relative_humidity', exportedGrid)
       CALL SetUnits ('% 0-100', exportedGrid) 
       !if file exists, remove it
       export_file = TRIM(export_path) //  'relative_humidity.nc'
       IF ( FileExists (export_file) ) THEN
          CALL FileDelete (export_file)
       END IF
       
       !variance of kriging 
       CALL SetLongName ( 'relative_humidity_variance', exportedGridVar)
       CALL SetStandardName ( 'relative_humidity_variance', exportedGridVar)
       CALL SetUnits ('% 0-100', exportedGridVar) !this unit is for exporting grid
       !if file exists, remove it
       export_file_var = TRIM(export_path) //  'relative_humidity_variance.nc'
       IF ( FileExists (export_file_var) ) THEN
          CALL FileDelete (export_file_var)
       END IF
       
     END IF

  END IF
	
	!complete initialization

  IF (interpolationMethod == 0) THEN
		!Get the dt of imported  field. Assume dt is regular	
		dtGrid = GetDtGrid (filename = fileGrid, checkRegular = .TRUE.)
		!check dt is multiple of dtGrid
        
        IF (.NOT.(MOD(dtRelHumidity,dtGrid) == 0)) THEN
            CALL Catch ('error', 'AirRelativeHumidity',   &
                'dt relative humidity is not multiple of dt of input grid')
        END IF
   ELSE
        !populate  metadata
        CALL ReadMetadata (fileunit, hygrometers)

        !check spatial reference system
        IF ( .NOT. hygrometers % mapping == mask % grid_mapping)  THEN
            CALL Catch ('info', 'AirRelativeHumidity',   &
		              'converting coordinate of stations')
            !convert stations' coordinate
            point1 % system = hygrometers % mapping
            point2 % system = mask % grid_mapping
            hygrometers % mapping = mask % grid_mapping
            DO i = 1, hygrometers % countObs
              point1 % easting = hygrometers % obs (i) % xyz % easting
              point1 % northing = hygrometers % obs (i) % xyz % northing
              point1 % elevation = hygrometers % obs (i) % z
              CALL Convert (point1, point2)
              hygrometers % obs (i) % xyz % easting = point2 % easting
              hygrometers % obs (i) % xyz % northing = point2 % northing 
            END DO
        END IF
                         
              
       
  END IF
   
RETURN
END SUBROUTINE AirRelativeHumidityInit

!==============================================================================
!| Description:
!   Read air relative humidity data
SUBROUTINE AirRelativeHumidityRead &
!
( time )

IMPLICIT NONE

!Arguments with intent(in):
TYPE (DateTime), INTENT(IN) :: time !!current time

!local declarations:
TYPE (DateTime) :: time_toread !! time to start reading from
CHARACTER (LEN = 300) :: filename
CHARACTER (LEN = 300) :: varname
INTEGER (KIND = short) :: i, j

!-------------------------end of declarations----------------------------------

IF ( .NOT. (time < timeNew) ) THEN
   
   time_toread = time + - (dtRelHumidity - hygrometers % timeIncrement)
   timeString = time_toread
   CALL Catch ('info', 'AirRelativeHumidity',   &
		                 'read new relative humidity data: ', &
                     argument = timeString)
   
   
   SELECT CASE (interpolationMethod)
     CASE (0) !input grid
       
          CALL ReadField (fileGrid,  time_toread, &
                        dtRelHumidity, dtGrid, &
                        'M', relHumidityAir, &
                         varName = relHumidityAir % var_name)
      
      
     CASE DEFAULT !requires interpolation
      !read new  data
      CALL ReadData (network = hygrometers, fileunit = fileunit, &
                      time = time_toread, aggr_time = dtRelHumidity, &
                      aggr_type = 'ave', tresh = valid_prcn)
      
         
        IF (interpolationMethod_assignment == 1) THEN !only one method is applied
                
                CALL Interpolate (network = hygrometers, &
                            method = interpolationMethod, &
                            near = neighbors, &
                            idw_power = idw_power, & 
                            anisotropy = krige_anisotropy, &
                            varmodel = krige_varmodel, &
                            lags = krige_lags, &
                            maxlag = krige_maxlag, &
                            grid = relHumidityAir, &
                            devst = grid_devst) 
                
        ELSE
            !loop trough interpolation methods
            DO i = 1, 3
                IF (interpolationMethod_vector(i) > 0) THEN
                      
                    CALL Interpolate (network = hygrometers, &
                            method = interpolationMethod_vector(i), &
                            near = neighbors, &
                            idw_power = idw_power, & 
                            anisotropy = krige_anisotropy, &
                            varmodel = krige_varmodel, &
                            lags = krige_lags, &
                            maxlag = krige_maxlag, &
                            grid =  interpolatedMap (i), &
                            devst = grid_devst) 
                    
                END IF
            END DO

            !compose the final interpolated field
            DO i = 1, interpolationMethod_map % idim
                DO j = 1, interpolationMethod_map % jdim
                    IF (interpolationMethod_map % mat(i,j) /= &
                        interpolationMethod_map % nodata ) THEN
                        relHumidityAir % mat (i,j) = &
                        interpolatedMap (interpolationMethod_map % mat(i,j)) % mat(i,j)
                    END IF
                END DO
            END DO

        END IF  !1 or more interpolation methods       

	END SELECT

  !apply scale factor and offset, if defined
	IF (offset_value /= MISSING_DEF_REAL) THEN
	   CALL Offset (relHumidityAir, offset_value)
	END IF
	
	
	IF (scale_factor /= MISSING_DEF_REAL) THEN
	   CALL Scale (relHumidityAir, scale_factor)
	END IF


  !grid exporting
  IF(export > 0 ) THEN
	  IF( time == timeNewExport .AND. &
        time >= export_start .AND. &
        time <= export_stop ) THEN
        timeString = time
        timeString = timeString(1:19)
        timeString(14:14) = '-'
		    timeString(17:17) = '-'
        
        grid_devst % reference_time = relHumidityAir % reference_time
        IF (needConversion) THEN
           CALL GridConvert (relHumidityAir, exportedGrid)
           CALL GridConvert (grid_devst, exportedGridVar)
        ELSE
           exportedGrid = relHumidityAir
           exportedGridVar = grid_devst
        END IF 

        SELECT CASE (export_format)
        CASE (1) !esri-ascii
              export_file = TRIM(export_path) //  TRIM(timeString) // &
                           '_relative_humidity.asc'
              CALL Catch ('info', 'AirRelativeHumidity',   &
		                       'exporting grid to file: ', &
                           argument = TRIM(export_file))
              CALL ExportGrid (exportedGrid, export_file, ESRI_ASCII)
              
              IF (krige_var == 1) THEN !export kriging variance
                    export_file_var = TRIM(export_path) //  TRIM(timeString) // &
                           '_relative_humidity_variance.asc'
                    CALL Catch ('info', 'AirRelativeHumidity',   &
		                       'exporting variance grid to file: ', &
                              argument = TRIM(export_file_var))
                    CALL ExportGrid (exportedGridVar, export_file_var, ESRI_ASCII)
              END IF
              
        CASE (2) !esri-binary
              export_file = TRIM(export_path) //  TRIM(timeString) // &
                           '_relative_humidity'
              CALL Catch ('info', 'AirRelativeHumidity',   &
		                       'exporting grid to file: ', &
                           argument = TRIM(export_file))
              CALL ExportGrid (exportedGrid, export_file, ESRI_BINARY)
              
              IF (krige_var == 1) THEN !export kriging variance
                   export_file_var = TRIM(export_path) //  TRIM(timeString) // &
                               '_relative_humidity_variance'
                   CALL Catch ('info', 'AirRelativeHumidity',   &
		                       'exporting variance grid to file: ', &
                              argument = TRIM(export_file_var))
                   CALL ExportGrid (exportedGridVar, export_file_var, ESRI_BINARY)
              END IF
              
        CASE (3) !net_cdf
              CALL SetCurrentTime (time, exportedGrid)
              CALL Catch ('info', 'AirRelativeHumidity',   &
                           'exporting grid to file: ', &
                           argument = TRIM(export_file))
              CALL ExportGrid (exportedGrid, export_file, 'relative_humidity', 'append')
              
              IF (krige_var == 1) THEN !export kriging variance
                  CALL SetCurrentTime (time, exportedGridVar)
                  CALL Catch ('info', 'AirRelativeHumidity',   &
		                       'exporting grid to file: ', &
                              argument = TRIM(export_file_var))
                 CALL ExportGrid (exportedGridVar, export_file_var, &
                                'relative_humidity_variance', 'append')
              END IF
        END SELECT
        timeNewExport = timeNewExport + export_dt
    END IF
  ENDIF

  !time forward
  timeNew = timeNew + dtRelHumidity
END IF

RETURN
END SUBROUTINE AirRelativeHumidityRead


!==============================================================================
!| Description:
!   set properties and initialize variables for each interpolation method
SUBROUTINE SetSpecificProperties &
!
( method, ini, mask )

IMPLICIT NONE

!Arguments with intent(in):
INTEGER (KIND = short), INTENT(in) :: method
TYPE (IniList)        , INTENT(in) :: ini
TYPE (grid_integer)   , INTENT(in) :: mask

!----------------------------end of declarations-------------------------------

!set data specific for each interpolation method
	SELECT CASE (method)
    CASE (1) !thiessen
      CALL NewGrid (interpolatedMap (1), mask, 0.)
    CASE (2) !inverse distance
      CALL NewGrid (interpolatedMap (2), mask, 0.)
	    !nearest-points
      IF (KeyIsPresent ('nearest-points', ini, &
                         section = 'relative-humidity') ) THEN
	       neighbors = IniReadInt ('nearest-points', ini, &
                                   section = 'relative-humidity')
      ELSE !nearest-points missing
          CALL Catch ('error', 'AirRelativeHumidity',   &
		                 'nearest-points missing in meteo configuration file')
      END IF
 
    CASE (3) !kriging
      CALL NewGrid (interpolatedMap (3), mask, 0.)
      !nearest-points
      IF (KeyIsPresent ('nearest-points', ini, &
                         section = 'relative-humidity') ) THEN
	       neighbors = IniReadInt ('nearest-points', ini, &
                                   section = 'relative-humidity')
           CALL Catch ('info', 'AirRelativeHumidity', &
                     'neighbors set to: ', argument = ToString (neighbors) )
      ELSE !nearest-points missing
          CALL Catch ('error', 'AirRelativeHumidity',   &
		                 'nearest-points missing in meteo configuration file')
      END IF
      
      !kriging-variance
      IF (KeyIsPresent ('kriging-variance', ini, &
                         section = 'relative-humidity') ) THEN
	       krige_var = IniReadInt ('kriging-variance', ini, &
                                   section = 'relative-humidity')
           
           CALL Catch ('info', 'AirRelativeHumidity',   &
		                 'kriging variance export set to ', argument = ToString(krige_var) )
      ELSE !kriging-variance missing
           krige_var = 0                                     
           CALL Catch ('info', 'AirRelativeHumidity',   &
		                 'kriging variance export set to default (0)')
      END IF
      
      !kriging-anisotropy
      IF (KeyIsPresent ('kriging-anisotropy', ini, &
                         section = 'relative-humidity') ) THEN
	       krige_anisotropy = IniReadInt ('kriging-anisotropy', ini, &
                                   section = 'relative-humidity')
           CALL Catch ('info', 'AirRelativeHumidity', &
                  'kriging anisotropy set to: ', argument = ToString (krige_anisotropy) )
      ELSE !kriging-anisotropy missing
           krige_anisotropy = 0                                     
           CALL Catch ('info', 'AirRelativeHumidity',   &
		                 'kriging anisotropy set to default (0)')
      END IF
      
      !kriging-variogram-model
      IF (KeyIsPresent ('kriging-variogram-model', ini, &
                         section = 'relative-humidity') ) THEN
	       krige_varmodel = IniReadInt ('kriging-variogram-model', ini, &
                                   section = 'relative-humidity')
           CALL Catch ('info', 'AirRelativeHumidity',&
                     'kriging variogram model set to: ', argument = ToString (krige_varmodel) )
           IF (krige_varmodel == 0 ) krige_varmodel = 5 !automatic fitting
      ELSE !kriging-variogram-model
           krige_varmodel = 2                                     
           CALL Catch ('info', 'AirRelativeHumidity',   &
		                 'kriging variogram model set to default (2 exponential)')
      END IF
      
      !kriging-lags
      IF (KeyIsPresent ('kriging-lags', ini, &
                         section = 'relative-humidity') ) THEN
	       krige_lags = IniReadInt ('kriging-lags', ini, &
                                   section = 'relative-humidity')
           IF (krige_lags == 0) krige_lags = 15
           CALL Catch ('info', 'AirRelativeHumidity', &
                    'kriging lags set to: ', argument = ToString (krige_lags) )
      ELSE !kriging-variogram-model
           krige_lags = 15                                     
           CALL Catch ('info', 'AirRelativeHumidity',   &
		                 'kriging lags set to default (15)')
      END IF
      
       !kriging-maxlag
      IF (KeyIsPresent ('kriging-maxlag', ini, &
                         section = 'relative-humidity') ) THEN
	       krige_maxlag = IniReadInt ('kriging-maxlag', ini, &
                                   section = 'relative-humidity')
           CALL Catch ('info', 'AirRelativeHumidity', &
                           'kriging max lag set to: ', argument = ToString (krige_maxlag) )
      ELSE !kriging-maxlag missing
           krige_maxlag = 0
          CALL Catch ('error', 'AirRelativeHumidity',   &
		                 'kriging max lag set to default (0)')
      END IF
	
	END SELECT


RETURN
END SUBROUTINE SetSpecificProperties


END MODULE AirRelativeHumidity